// Top-level build file where you can add configuration options common to all
// sub-projects/modules.
buildscript {
	repositories {
		jcenter()
		mavenCentral()
	}
	dependencies {
		classpath 'com.android.tools.build:gradle:1.3.1'
	}
}

allprojects {
	repositories {
	}
}

apply plugin: 'com.android.application'

repositories {
    flatDir {
        dirs 'libs/3rdParty/jcenter', 'libs/3rdParty/maven'
    }
}

dependencies {
    // Local JAR files
    //compile fileTree(dir: 'libs/zxing', includes: ['core-3.1.0.jar', 'android-integration-3.1.0.jar'])
	compile name: 'zxing-core-3.2.1' //zxing
	compile name: 'zxing-android-integration-3.2.1' //zxing
    compile name: 'libidn-1.15'
    compile name: 'minidns-0.1.7'
    compile name: 'org.otr4j-0.22'
    compile name: 'bcprov-jdk15on-1.52'
    compile name: 'bcmail-jdk15on-1.52'
    compile name: 'bcpkix-jdk15on-1.52'
    compile name: 'EnhancedListView-0.3.4', ext: 'aar'
    compile name: 'ShortcutBadger-1.1.3', ext: 'aar'
    compile name: 'swipy-1.2.1', ext: 'aar'
	compile name: 'axolotl-android-1.3.4', ext: 'aar'
    compile name: 'axolotl-java-1.3.4'
    compile name: 'curve25519-android-0.2.4', ext: 'aar' // axolotl, loaded from jcenter
    compile name: 'curve25519-java-0.2.4' // axolotl, loaded from jcenter
    compile name: 'android-crop-1.0.1', ext: 'aar'
    compile name: 'roundedimageview-2.2.0', ext: 'aar'
    compile name: 'switchbutton-1.2.8', ext: 'aar' // loaded from jcenter
    compile name: 'openpgp-api-10.0', ext: 'aar' // loaded from jcenter

    // Local modules
    compile project(':libs:MemorizingTrustManager')
    compile project(':libs:emojicon')
	compile project(':libs:colorpicker')
	compile project(':libs:thedevstacklogcat')

    // Android dependencies
    compile 'com.android.support:support-v13:21.0.3'
}

android {
	compileSdkVersion 23
	buildToolsVersion "23.0.2"

	defaultConfig {
		minSdkVersion 14
		targetSdkVersion 23
		versionCode 122
		versionName "1.9.3.1"
		project.ext.set(archivesBaseName, archivesBaseName + "-" + versionName);
	}

	compileOptions {
		sourceCompatibility JavaVersion.VERSION_1_7
		targetCompatibility JavaVersion.VERSION_1_7
	}

	//
	// To sign release builds, create the file `gradle.properties` in
	// $HOME/.gradle or in your project directory with this content:
	//
	// mStoreFile=/path/to/key.store
	// mStorePassword=xxx
	// mKeyAlias=alias
	// mKeyPassword=xxx
	//
	if (project.hasProperty('mStoreFile') &&
			project.hasProperty('mStorePassword') &&
			project.hasProperty('mKeyAlias') &&
			project.hasProperty('mKeyPassword')) {
		signingConfigs {
			release {
				storeFile file(mStoreFile)
					storePassword mStorePassword
					keyAlias mKeyAlias
					keyPassword mKeyPassword
			}
		}
		buildTypes.release.signingConfig = signingConfigs.release
	} else {
		buildTypes.release.signingConfig = null
	}

	applicationVariants.all { variant ->
		if (variant.name.equals('release')) {
			variant.outputs.each { output ->
				if (output.zipAlign != null) {
					output.zipAlign.outputFile = new File(output.outputFile.parent, rootProject.name + "-${variant.versionName}.apk")
				}
				output.packageApplication.outputFile = new File(output.outputFile.parent, output.packageApplication.outputFile.name
					.replace(".apk", "-${variant.versionName}.apk"))
			}
		}
	}

	lintOptions {
		disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
	}

	subprojects {

		afterEvaluate {
			if (getPlugins().hasPlugin('android') ||
					getPlugins().hasPlugin('android-library')) {

				configure(android.lintOptions) {
					disable 'AndroidGradlePluginVersion', 'MissingTranslation'
				}
			}

		}
	}
}