// Top-level build file where you can add configuration options common to all
// sub-projects/modules.
buildscript {
	repositories {
		jcenter()
		mavenCentral()
	}
	dependencies {
		classpath 'com.android.tools.build:gradle:1.2.3'
	}
}

allprojects {
	repositories {
		jcenter()
		mavenCentral()
	}
}

apply plugin: 'com.android.application'

repositories {
    flatDir {
        dirs 'libs/3rdParty', 'libs/3rdParty/zxing'
    }
}

dependencies {
    // Local JAR files
    //compile fileTree(dir: 'libs/zxing', includes: ['core-3.1.0.jar', 'android-integration-3.1.0.jar'])
	compile name: 'core-3.1.0' //zxing
	compile name: 'android-integration-3.1.0' //zxing
    compile name: 'libidn-1.15'
    compile name: 'minidns-0.1.3'
    compile name: 'org.otr4j-0.22'
    compile name: 'bcprov-jdk15on-1.51'
    compile name: 'EnhancedListView-0.3.4', ext: 'aar'
    compile name: 'ShortcutBadger-1.1.1', ext: 'aar'
    compile name: 'swipy-1.2.1', ext: 'aar'

    // Local modules
    compile project(':libs:openpgp-api-lib')
    compile project(':libs:MemorizingTrustManager')
    compile project(':libs:emojicon')
	compile project(':libs:colorpicker')
	compile project(':libs:thedevstacklogcat')

    // Android dependencies
    compile 'com.android.support:support-v13:21.0.3'
}

android {
	compileSdkVersion 22
	buildToolsVersion "22.0.1"

	defaultConfig {
		minSdkVersion 14
		targetSdkVersion 21
		versionCode 5
		versionName "0.0.5"
	}

	compileOptions {
		sourceCompatibility JavaVersion.VERSION_1_7
		targetCompatibility JavaVersion.VERSION_1_7
	}

	//
	// To sign release builds, create the file `gradle.properties` in
	// $HOME/.gradle or in your project directory with this content:
	//
	// mStoreFile=/path/to/key.store
	// mStorePassword=xxx
	// mKeyAlias=alias
	// mKeyPassword=xxx
	//
	if (project.hasProperty('mStoreFile') &&
			project.hasProperty('mStorePassword') &&
			project.hasProperty('mKeyAlias') &&
			project.hasProperty('mKeyPassword')) {
		signingConfigs {
			release {
				storeFile file(mStoreFile)
					storePassword mStorePassword
					keyAlias mKeyAlias
					keyPassword mKeyPassword
			}
		}
		buildTypes.release.signingConfig = signingConfigs.release
	} else {
		buildTypes.release.signingConfig = null
	}

	applicationVariants.all { variant ->
		if (variant.name.equals('release')) {
			variant.outputs.each { output ->
				if (output.zipAlign != null) {
					output.zipAlign.outputFile = new File(output.outputFile.parent, "ConversationsPlus-${variant.versionName}.apk")
				}
				output.packageApplication.outputFile = new File(output.outputFile.parent, output.packageApplication.outputFile.name
					.replace(".apk", "-${variant.versionName}.apk"))
			}
		}
	}

	lintOptions {
		disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity'
	}

	subprojects {

		afterEvaluate {
			if (getPlugins().hasPlugin('android') ||
					getPlugins().hasPlugin('android-library')) {

				configure(android.lintOptions) {
					disable 'AndroidGradlePluginVersion', 'MissingTranslation'
				}
			}

		}
	}
}