// Top-level build file where you can add configuration options common to all
// sub-projects/modules.
buildscript {
    repositories {
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.2.3'
    }
}

apply plugin: 'com.android.application'

repositories {
    jcenter()
    mavenCentral()
}

allprojects {
    repositories {
        maven { url "https://jitpack.io" }
    }
}

configurations {
    playstoreCompile
}

dependencies {
    compile project(':libs:MemorizingTrustManager')
    compile project(':libs:audiowife')
    compile project(':libs:emojicon')
    compile project(':libs:android-transcoder')
    playstoreCompile 'com.google.android.gms:play-services-gcm:10.0.1'
    compile 'org.sufficientlysecure:openpgp-api:10.0'
    compile 'com.soundcloud.android:android-crop:1.0.1@aar'
    compile 'com.android.support:support-v13:25.1.1'
    compile 'org.bouncycastle:bcprov-jdk15on:1.56'
    compile 'org.bouncycastle:bcmail-jdk15on:1.56'
    compile 'org.jitsi:org.otr4j:0.22'
    compile 'org.gnu.inet:libidn:1.15'
    compile 'com.google.zxing:core:3.3.0'
    compile 'com.google.zxing:android-integration:3.3.0'
    compile 'de.measite.minidns:minidns:0.1.7'
    compile 'de.timroes.android:EnhancedListView:0.3.4'
    compile 'me.leolin:ShortcutBadger:1.1.11@aar'
    compile 'com.kyleduo.switchbutton:library:1.2.8'
    compile 'org.whispersystems:axolotl-android:1.4.3'
    compile 'com.makeramen:roundedimageview:2.3.0'
    compile 'jetty:javax.servlet:5.1.12'
    compile 'com.google.code.gson:gson:2.4'
    compile 'org.jbundle.util.osgi.wrapped:org.jbundle.util.osgi.wrapped.org.apache.http.client:4.1.2'
    compile 'com.android.support:appcompat-v7:25.1.1'
    compile 'com.android.support:multidex:1.0.1'
    compile 'com.github.bumptech.glide:glide:3.7.0'
    compile 'com.github.chrisbanes:PhotoView:1.3.1'
    compile 'com.github.rtoshiro.fullscreenvideoview:fullscreenvideoview:1.1.2'
    compile 'com.google.android.gms:play-services-location:10.0.1'
    compile 'com.google.android.gms:play-services-maps:10.0.1'
    compile 'pub.devrel:easypermissions:0.2.1'
    compile 'com.wefika:flowlayout:0.4.1'
    compile 'com.googlecode.ez-vcard:ez-vcard:0.10.1'
}

ext {
    travisBuild = System.getenv("TRAVIS") == "true"
    // allows for -Dpre-dex=false to be set
    preDexEnabled = "true".equals(System.getProperty("pre-dex", "true"))
}

android {

    compileSdkVersion 25
    buildToolsVersion "25.0.2"

    defaultConfig {
        minSdkVersion 14
        targetSdkVersion 25

        versionCode 188
        versionName "1.16.3"

        archivesBaseName += "-$versionName"
        applicationId "de.pixart.messenger"
        multiDexEnabled true
        buildConfigField("String", "XMPP_IP", '"185.26.156.37"')
        buildConfigField("Integer[]", "XMPP_Ports", "{61000, 65000}")
        buildConfigField("String", "DOMAIN_LOCK", '"pix-art.de"')
        buildConfigField("String", "UPDATE_URL", '"http://xmpp.pix-art.de/Pix-Art_Messenger/update/"')
    }

    dexOptions {
        // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
        preDexLibraries = preDexEnabled && !travisBuild
        javaMaxHeapSize "4g"
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }

    productFlavors {
        playstore
        free
        open {
            buildConfigField("String", "XMPP_IP", "null")
            buildConfigField("Integer[]", "XMPP_Ports", "null")
            buildConfigField("String", "DOMAIN_LOCK", "null")
            buildConfigField("String", "UPDATE_URL", '"http://xmpp.pix-art.de/Pix-Art_Messenger/update/open/"')
            applicationId "de.pixart.openmessenger"
        }
    }
    if (project.hasProperty('mStoreFile') &&
            project.hasProperty('mStorePassword') &&
            project.hasProperty('mKeyAlias') &&
            project.hasProperty('mKeyPassword')) {
        signingConfigs {
            release {
                storeFile file(mStoreFile)
                storePassword mStorePassword
                keyAlias mKeyAlias
                keyPassword mKeyPassword
            }
        }
        buildTypes {
            debug {
                minSdkVersion 14
                debuggable true
                buildTypes.release.signingConfig = null
                //applicationIdSuffix ".debug"
            }

            release {
                debuggable false
                signingConfig = signingConfigs.release
                minifyEnabled true
                runProguard true
                proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            }
        }
    }

    lintOptions {
        disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
    }

    subprojects {

        afterEvaluate {
            if (getPlugins().hasPlugin('android') ||
                    getPlugins().hasPlugin('android-library')) {

                configure(android.lintOptions) {
                    disable 'AndroidGradlePluginVersion', 'MissingTranslation'
                }
            }

        }
    }

    packagingOptions {
        exclude 'META-INF/BCKEY.DSA'
        exclude 'META-INF/BCKEY.SF'
    }
}