// Top-level build file where you can add configuration options common to all
// sub-projects/modules.
buildscript {
    repositories {
        maven {
            url "https://mvn.thedevstack.de/mvn"
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.4.1'
    }
}

apply plugin: 'com.android.application'

allprojects {
    repositories {
        maven {
            url "https://mvn.thedevstack.de/mvn"
        }
    }
}

repositories {
    maven {
        url "https://mvn.thedevstack.de/mvn"
    }
}

configurations {
    standardPushImplementation
}

dependencies {
    implementation project(':libs:android-transcoder')
    standardPushImplementation ('com.google.firebase:firebase-messaging:17.3.4') {
        exclude group: 'com.google.firebase', module: 'firebase-core'
        exclude group: 'com.google.firebase', module: 'firebase-analytics'
        exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
    }
    implementation 'org.sufficientlysecure:openpgp-api:10.0'
    implementation('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
        exclude group: 'com.android.support', module: 'appcompat-v7'
        exclude group: 'com.android.support', module: 'exifinterface'
    }
    implementation 'org.bouncycastle:bcmail-jdk15on:1.58'
    implementation 'org.jitsi:org.otr4j:0.22'
    implementation 'org.gnu.inet:libidn:1.15'
    implementation 'com.google.zxing:core:3.3.3'
    implementation 'de.measite.minidns:minidns-hla:0.2.4'
    implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
    implementation 'org.whispersystems:signal-protocol-java:2.6.2'
    implementation 'com.makeramen:roundedimageview:2.3.0'
    implementation 'jetty:javax.servlet:5.1.12'
    implementation 'com.google.code.gson:gson:2.8.2'
    implementation 'com.android.support:multidex:1.0.3'
    implementation 'com.android.support:support-v13:28.0.0'
    implementation 'com.android.support:appcompat-v7:28.0.0'
    implementation 'com.android.support:exifinterface:28.0.0'
    implementation 'com.android.support:support-v4:28.0.0'
    implementation 'com.android.support:support-emoji:28.0.0'
    implementation 'com.android.support:support-emoji-bundled:28.0.0'
    implementation 'com.android.support:support-emoji-appcompat:28.0.0'
    implementation 'com.android.support:exifinterface:28.0.0'
    implementation 'com.android.support:design:28.0.0'
    implementation 'com.android.support:cardview-v7:28.0.0'
    implementation 'com.davemorrissey.labs:subsampling-scale-image-view:3.10.0'
    implementation project(':libs:fullscreenvideoview')
    implementation 'pub.devrel:easypermissions:2.0.0'
    implementation 'com.wefika:flowlayout:0.4.1'
    implementation 'com.googlecode.ez-vcard:ez-vcard:0.10.5'
    implementation project(':libs:xmpp-addr')
    implementation 'org.hsluv:hsluv:0.2'
    implementation 'org.conscrypt:conscrypt-android:1.4.2'
    implementation 'pl.droidsonroids.gif:android-gif-drawable:1.2.15' // 1.2.15 is last working version for minSDK 16
    implementation 'me.drakeet.support:toastcompat:1.1.0'
    implementation 'org.osmdroid:osmdroid-android:6.0.3'
    implementation 'com.leinardi.android:speed-dial:2.0.1'
    implementation 'com.squareup.picasso:picasso:2.71828'
    implementation 'com.squareup.okhttp3:okhttp:3.12.2' // versions > 3.12.x don't support API level < 21 anymore
    implementation 'com.squareup.retrofit2:retrofit:2.5.0'
    implementation 'com.squareup.retrofit2:converter-gson:2.5.0'
    implementation 'com.google.guava:guava:27.1-android'
    implementation project(':libs:thedevstacklogcat')
}

ext {
    travisBuild = System.getenv("TRAVIS") == "true"
    preDexEnabled = System.getProperty("pre-dex", "true")
}


android {

    compileSdkVersion 28

    def appId = "de.thedevstack.piratx"

    defaultConfig {
        minSdkVersion 16
        targetSdkVersion 28

        versionCode 3
        versionName "0.0.3"

        archivesBaseName += "-$versionName"
        applicationId appId
        multiDexEnabled true
        resValue "string", "applicationId", applicationId
        resValue "string", "app_name", "PiratX"

        buildConfigField 'String', 'STATICMAP_URL', '"https://piratx.thedevstack.de/staticmap"'
        buildConfigField 'String', 'INVITE_HOST', '"jabber.thedevstack.de"'
        buildConfigField 'String', 'TERMS_OF_USE_URL', '"https://piratx.thedevstack.de/termsofuse.html"'
        buildConfigField 'String', 'PRIVACY_URL', '"https://piratx.thedevstack.de/privacy.html"'
    }

    dataBinding {
        enabled true
    }

    dexOptions {
        // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
        preDexLibraries = preDexEnabled && !travisBuild
        javaMaxHeapSize "8g"
        jumboMode true
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    flavorDimensions("distribution", "domain", "stage")

    productFlavors {
        beta {
            dimension "stage"
            applicationIdSuffix ".beta"
            versionNameSuffix "-beta"
            resValue "string", "app_name", "PiratX BETA"
        }
        allDomain {
            dimension "domain"
            buildConfigField 'String', 'FIXED_DOMAIN', 'null'
        }
        huaraka {
            dimension "domain"
            applicationIdSuffix ".huaraka"
            versionNameSuffix "-huaraka"
            buildConfigField 'String', 'FIXED_DOMAIN', '"jabber.huaraka.de"'
        }
        piratx {
            dimension "distribution"
        }
        standardPush {
            dimension "distribution"
        }
        standard {
            dimension "distribution"
        }
    }
    if (project.hasProperty('mStoreFile') &&
            project.hasProperty('mStorePassword') &&
            project.hasProperty('mKeyAlias') &&
            project.hasProperty('mKeyPassword')) {
        signingConfigs {
            release {
                storeFile file(mStoreFile)
                storePassword mStorePassword
                keyAlias mKeyAlias
                keyPassword mKeyPassword
            }
        }
        buildTypes {
            release {
                debuggable false
                signingConfig = signingConfigs.release
                minifyEnabled true
                shrinkResources true
                runProguard true
                proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            }

            debug {
                debuggable true
                buildTypes.release.signingConfig = null
                minifyEnabled true
                shrinkResources true
                runProguard true
                proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            }

        }
    }

    lintOptions {
        disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource', 'RestrictedApi'
        //abortOnError false
    }

    subprojects {

        afterEvaluate {
            if (getPlugins().hasPlugin('android') ||
                    getPlugins().hasPlugin('android-library')) {

                configure(android.lintOptions) {
                    disable 'AndroidGradlePluginVersion', 'MissingTranslation'
                }
            }

        }
    }

    packagingOptions {
        exclude 'META-INF/BCKEY.DSA'
        exclude 'META-INF/BCKEY.SF'
    }
}